帮助中心

这里有最新的使用文档和教程

< 返回

windows 通过BAT脚本设置IP、DNS、

2023-05-30 14:12 作者:31IDC 阅读量:899 所属分类:Windows系统

Windows 通过BAT脚本设置IP、DNS

 

本文通过BAT脚本,实现在WIN7上设置IP等网络信息,以下是示例:

以下是脚本:
@ echo off
%1 %2
ver|find "5.">nul&&goto :st
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :st","","runas",1)(window.close)&goto :eof

:st

echo/
title 修改本机IP地址
color 1f
echo *****************************************************************
echo *                                                               *
echo *                    修改本机网卡IP地址                         *
echo *                        1.静态地址                             *
echo *                        2.自动获取                             *
echo *****************************************************************
:begin
set /p n=请输入要设置的网卡类型(1或2):
if "%n%" lss "1" echo 您输入的网卡不存在!请重新输入!!!
if "%n%" gtr "2" echo 您输入的网卡不存在!请重新输入!!!
echo/
if "%n%" lss "1" goto begin
if "%n%" gtr "2" goto begin 
if "%n%" equ "1" goto x1
if "%n%" equ "2" goto x2

:x1
echo 您选择的是:%n%.以太网
:begin1
set /p a=  请输入静态IP地址(如 192.168.1.2):
if "%a%" equ "" goto begin1
:begin2
set /p b=  请输入子网掩码(如 255.255.255.0):
if "%b%" equ "" goto begin2
:begin3
set /p c=  请输入网关地址(如 192.168.1.1):
if "%c%" equ "" goto begin3
:begin4
set /p d=  请输入DNS地址1(如 114.114.114.114):
if "%d%" equ "" goto begin4
:begin5
set /p e=  请输入DNS地址2(如 211.138.156.66):
if "%e%" equ "" goto begin5
:begin6
set /p f=  请输入WINS地址(如 8.8.8.8):
if "%f%" equ "" goto begin6
netsh interface ip set address "本地连接" static %a% %b% %c%
netsh interface ip set dns "本地连接" static %d% primary>nul
netsh interface ip add dns "本地连接" %e%>nul
netsh interface ip set wins "本地连接" static %f%>nul
echo  静态地址设置成功!!!
ping -n 5 127.0.0.1>nul
goto:eof

:x2
echo 选择的是:%n%.自动获取
echo *******************************************************
echo *        IP即将初始化为自动获取状态……                 *
netsh interface ip set address "本地连接" dhcp>nul
netsh interface ip set dns "本地连接" dhcp>nul
echo *******************************************************
echo DHCP设置成功!!!
ping -n 5 127.0.0.1>nul
goto:eof

pause

31IDC - 12 年深耕海外 IDC 高端资源